Way to simulate Dual Pane

[gyrof]

Hi,
I have been looking for a way to simulate a dual pane configuration in PathFinder. One simple idea I had is to bring up two PF browsers and size and arrange them side by side. However, I don't want to have to do this manually every time. Can anyone give me a hint as to how I might use AppleScript to accomplish this?

Thanks.

-g

[nightofneih]

I would also love to have a dual pane view. I regularly have at least two finder windows open at all time.

[neilio]

This is already on our feature request list, so we'll be looking into the possibility of integrating this for a future release.

[R-I-P]

Hi,
I have been looking for a way to simulate a dual pane configuration in PathFinder. One simple idea I had is to bring up two PF browsers and size and arrange them side by side. However, I don't want to have to do this manually every time. Can anyone give me a hint as to how I might use AppleScript to accomplish this?

Thanks.

-g

I found this tread: http://www.macosxhints.com/article.php?story=20060105082728937&lsrc=osxh

I have not been able to make this work unfortunately. Maybe someone here has the expertise?

[flip]

I posted my solution in this message: http://www.cocoatech.com/forum/showpost.php?p=13019&postcount=2.

[redrocklobster]

Here's my Path Finder modification of 2Wind, a script to create two Finder windows on top of each other. Thanks to flip for some pointers.

Use the properties to adjust your settings, espcially monitor dimensions.


-------------------


(*
This script opens two finely positioned Path Finder Windows, and optionally leaves space for and opens an Info Window

This is a Path Finder version of the finder Script

This script started with a script posted by Yuriwho on macosxhints.com:
<http://www.macosxhints.com/article.php?story=20011127022706921>

Several contributors posted their own modifications, including James Sorenson, whose script became a basis for this one.

WBC has re-written a good portion of it to make it much more flexible and easy to customize in the user settings section, below.

WBC has also added a cool finder icon of unknown source. The idea is that it can be placed in the doc or the toolbar or both.
If this is your icon and you want credit, please contact Wooden Brain Concepts:
http://www.woodenbrain.com
woodenbrain@kagi.com

version history:
1.0 released

branch history:
1.0 for path finder

*)

--True Monitor size
property monitor_width : 1440
property monitor_height : 900

--Thicknes of titlebars (to prevent overlapping; should probably remain set to 23)
property menubar : 40

--Margins to make room for iTunes, Dock, Desktop items, etc
property leftmargin : 3
property rightmargin : 10
property topmargin : 65
property bottommargin : 40
property gap_val : 5

(* notes on space values:
iTunes @ top left: topmargin = 68
small dock: bottommargin = 30
*)

property open_info : false -- open the info window?

--Height and width of the Info Window
property info_width : 330
property info_height : 335
property info_gap : 2 --gap beyond info_width to leave

--set one of these values to 1 (rather than 0) to leave space for info window

property info_top_left : 0
property info_top_right : 0
property info_bottom_left : 0
property info_bottom_right : 0

property hide_others : false --hide other visible applications?

--set folder defaults
(*
options for folders:
0. root (all volumes)
1. user home directory
2. user documents
*)

property folder1_pref : 0
property folder2_pref : 2

set startDir to path to startup disk
set homeDir to (path to "cusr" from user domain)

tell application "Path Finder"
--set default directories (see properties above)
if folder1_pref = 0 or folder1_pref > 2 then set folder1 to startDir
if folder1_pref = 1 then set folder1 to homeDir
if folder1_pref = 2 then set folder1 to ((homeDir as string) & "Documents") as alias
if folder2_pref = 0 or folder2_pref > 2 then set folder2 to startDir
if folder2_pref = 1 then set folder2 to homeDir
if folder2_pref = 2 then set folder2 to ((homeDir as string) & "Documents") as alias

-- necessary to use system events to set posix path
tell application "System Events" to set posixF1 to POSIX path of folder1

set vSpace to (monitor_height - (topmargin + bottommargin + gap_val + menubar))
set win_vSpace to round (vSpace / 2)
set win_hSpace to (monitor_width - (leftmargin + rightmargin))

close every finder window

-- TOP WINDOW
open folder1
set top_window to finder window 1

set bottom_of_top to monitor_height - bottommargin - win_vSpace - gap_val
--{left,top,right,bottom}
set the bounds of top_window to ¬
{leftmargin + ((info_width + info_gap) * info_top_left), ¬
topmargin + (menubar), ¬
monitor_width - rightmargin - ((info_width + info_gap) * info_top_right), ¬
bottom_of_top}

-- BOTTOM WINDOW
open folder2
set bot_window to finder window 1

--{left,top,right,bottom}
set the bounds of bot_window to ¬
{leftmargin + ((info_width + info_gap) * info_bottom_left), ¬
bottom_of_top + gap_val, ¬
monitor_width - rightmargin - ((info_width + info_gap) * info_bottom_right), ¬
monitor_height - bottommargin}

-- INFO WINDOW
if open_info then
--Applescript currently can't set the position or bounds of the Info Window.
--Just move it to where you want it, close it, then open it. From then on, it should open in the proper place
PFInfo posixF1
end if

--Reactivate windows
activate
if hide_others then
tell application "System Events"
set visible of (every process whose visible is true and frontmost is false) to false
end tell
end if

end tell

[Ian]

This is already on our feature request list, so we'll be looking into the possibility of integrating this for a future release.

I used to use XTree Gold on the PC years ago and working from one pane to another side by side was a great way to work.

Bring this on as soon as possible in my opinion!

[Hamster]

Here another one (for Finder): http://wb.raphaelwolfer.de/pages/mac-os-x.php
as Tip for coding.

Regards, Hamster